Secondary structures

ss_map(
    simulation::Simulation; 
    selection::Union{AbstractString,Function}=PDBTools.isprotein,
    ss_method=stride_run,
    show_progress=true
)

Calculates the secondary structure map of the trajectory. Returns a matrix of secondary structure codes, where each row is a residue and each column is a frame.

By default, all protein atoms are considered. The selection keyword argument can be used to choose a different selection. The PDBTools selection syntax can be used, for example selection="protein and chain A", or general Julia functions, like selection=at -> chain(at) in ('A', 'B').

The ss_method keyword argument can be used to choose the secondary structure prediction method, which can be either stride_run or dssp_run. The default is stride_run. STRIDE is a faster algorithm, while DSSP is the default one in PDB database.

The show_progress keyword argument controls whether a progress bar is shown.

For the classes, refer to the ProteinSecondaryStructures.jl package documentation.

Example

julia> using MolSimToolkit, MolSimToolkit.Testing

julia> simulation = Simulation(Testing.namd_pdb, Testing.namd_traj);

julia> ssmap = ss_map(simulation; selection="residue >= 30 and residue <= 35", show_progress=false)
6×5 Matrix{Int64}:
 5  9  5  5  5
 5  9  5  5  5
 5  1  5  5  5
 5  1  5  5  5
 5  1  5  5  5
 9  9  9  9  9

julia> ss_name.(ssmap)
6×5 Matrix{String}:
 "turn"  "coil"       "turn"  "turn"  "turn"
 "turn"  "coil"       "turn"  "turn"  "turn"
 "turn"  "310 helix"  "turn"  "turn"  "turn"
 "turn"  "310 helix"  "turn"  "turn"  "turn"
 "turn"  "310 helix"  "turn"  "turn"  "turn"
 "coil"  "coil"       "coil"  "coil"  "coil"

ss_heatmap(ssmap::Matrix{<:Real}; scalex=1.0, kargs...)

Plots a heatmap of the secondary structure map.

The scalex keyword argument can be used to scale the x-axis, which usually has the meaning of time in a simulation. By default, it is 1.0 and the x-axis is the frame number.

The kargs keyword arguments are passed to the heatmap function of the Plots package, to modify properties of the plot. In particular:

• the residue ticks can be set with yticks, and can be set to residue specific labels with the residue_ticks function of PDBTools.
• the x-axis label can be set with xlabel to appropriate units, such as "time / ns", in combination with scalex.

Example

julia> using MolSimToolkit, MolSimToolkit.Testing

julia> using Plots, PDBTools

julia> simulation = Simulation(Testing.namd_pdb, Testing.namd_traj);

julia> ssmap = ss_map(simulation; ss_method=stride_run, show_progress=false);

julia> protein = select(atoms(simulation), "protein");

julia> ss_heatmap(ssmap; scalex=0.1, xlabel="time / ns", yticks=residue_ticks(prot; stride=5))

Will plot a heatmap of the secondary structure map, with the x-axis scaled to 0.1, and residue ticks every 5 residues. The plot can be saved with the savefig function of the Plots package.

ss_mean(ssmap::AbstractMatrix{<:Integer}; class, dims=nothing)

Calculates the mean secondary structure class content of the trajectory, given the secondary structure map.

The secondary structure class to be considered must be defined by the class keyword argument.

class can be either a string, a character, or an integer, or a set of values, setting the class(es) of secondary structure to be consdiered. For example, for alpha helix, use "H". It can also be a vector of classes, such as class=["H", "E"].

The mean can be calculated along the residues (default) or along the frames, by setting the dims keyword argument.

• dims=nothing (default) calculates the mean occurence of ss_class of the whole matrix.
• dims=1 calculates the mean occurence of ss_class along the frames, for each residue.
• dims=2 calculates the mean occurence of ss_class along the residues, for each frame.

The classes can be found in the ProteinSecondaryStructures.jl package documentation.

Example

julia> using MolSimToolkit, MolSimToolkit.Testing

julia> simulation = Simulation(Testing.namd_pdb, Testing.namd_traj);

julia> ssmap = ss_map(simulation; # 5 frames 
                   selection="residue >= 30 and residue <= 35", # 6 residues
                   show_progress=false
               );

julia> ss_mean(ssmap; class="C")
0.23333333333333334

julia> ss_mean(ssmap; class="C", dims=1) # mean coil content per residue
5-element Vector{Float64}:
 0.16666666666666666
 0.5
 0.16666666666666666
 0.16666666666666666
 0.16666666666666666 

julia> ss_mean(ssmap; class="C", dims=2) # mean coil content per frame
6-element Vector{Float64}:
 0.2
 0.2
 0.0
 0.0
 0.0
 1.0

julia> ss_mean(ssmap; class=["C", "T"]) # mean coil or turn
0.9